Win10修改C:\Users\中文用户名

小黑

互联网新生代农民工

2022.07.31

脚本有朋友不成功，同学们先按照文下面步骤手动操作吧
有同学反馈修改之后微软账户密码错误，保险起见，修改前先退出微软账户

2022.02.08 更新

人终究会犯错,不如整个脚本?

如果你能成功执行脚本,那么这篇文章可以不用往下看了.

注：方法和代码均由作者原创，各位成功了我求个赞不过分吧（手动狗头）

源代码如下,也可自行新建 txt 文档, 粘贴代码, 修改后缀名为 bat, 双击执行

@REM 提升管理员权限: 用于修改注册表
@echo off
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"

SETLOCAL ENABLEDELAYEDEXPANSION
echo 当前用户为: %USERNAME%
echo 用户目录为: %USERPROFILE%
echo ==================================================
echo 输入修改用户名:
set /p name=
echo ==================================================

set dir=%USERPROFILE%
set "dir=!dir:%USERNAME%=%name%!"
echo 注: 新文件夹是旧文件夹的快捷方式,不影响原有数据
choice /m "确认将用户文件夹 \"%USERPROFILE%\" 修改为 \"%dir%\" "
if %ERRORLEVEL%==1 goto begin
if %ERRORLEVEL%==2 goto end

:end
echo 执行结束
goto dPause

:begin
echo ==================================================
echo No.1: 创建新文件夹并映射到旧文件夹
mklink /j %dir% %USERPROFILE%

echo ==================================================
echo No.2: 查找注册表
reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList" /s /f %USERPROFILE% /c /e | findstr "ProfileImagePath" && goto findSuccess || goto findError

:findError
echo 注册表查找失败,执行结束
goto dPause

:findSuccess
echo ==================================================
echo No.3: 修改注册表
for /f "delims=" %%i in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList" /s /f %%USERPROFILE%% /c /e ^| findstr "ProfileList"') do set key=%%i
reg add "%key%" /v "ProfileImagePath" /t REG_EXPAND_SZ /d %dir% /f
echo 修改注册表完成,所有工作均已完成

echo ==================================================
echo 请自行 重新登录 或者 重启, 以完成变更
goto dPause

:dPause
pause
echo 请自行 重新登录 或者 重启, 以完成变更
pause