apply plugin: 'org.jetbrains.kotlin.multiplatform'
apply plugin: 'com.squareup.sqldelight'
apply plugin: 'kotlinx-serialization'

sqldelight {
    AccountingDB {
        packageName = "com.littlegnal.accountingmultiplatform"
    }
}

kotlin {
    sourceSets {
        commonMain {
            dependencies {
                implementation deps.kotlin.stdlib.stdlib
                implementation deps.kotlin.serialiaztion.runtime.common
                implementation deps.kotlin.coroutines.common
            }
        }

        commonTest {
            dependencies {
                implementation deps.kotlin.coroutines.core
                implementation deps.kotlin.coroutines.common
                implementation deps.kotlin.coroutines.test
                implementation deps.kotlin.test.common
                implementation deps.kotlin.test.annotations
//                implementation deps.mockk.common
//                implementation deps.mockk.mockk
                implementation "io.mockk:mockk-common:1.9.3"
                implementation "io.mockk:mockk:1.9.3"

            }
        }

        androidTest {
            dependencies {
                implementation deps.kotlin.test.test
                implementation deps.kotlin.test.junit
            }
        }

        androidMain {
            dependencies {
                implementation deps.kotlin.stdlib.stdlib
                implementation deps.sqldelight.runtimejvm
                implementation deps.kotlin.serialiaztion.runtime.runtime
                implementation deps.kotlin.coroutines.android
            }
        }

        iosMain {
            dependencies {
                implementation deps.kotlin.stdlib.stdlib
                implementation deps.sqldelight.driver.ios
                implementation deps.kotlin.serialiaztion.runtime.native
                implementation deps.kotlin.coroutines.native
            }
        }

        iosTest {
            dependencies {
                implementation "io.mockk:mockk-common:1.9.3"
                implementation "io.mockk:mockk:1.9.3"
            }
        }
    }

    targets {
        fromPreset(presets.jvm, 'android')
        final def iOSTarget = System.getenv('SDK_NAME')?.startsWith("iphoneos") \
                              ? presets.iosArm64 : presets.iosX64

        fromPreset(iOSTarget, 'ios') {
            binaries {
                framework('common')
            }
        }
    }
}

// workaround for https://youtrack.jetbrains.com/issue/KT-27170
configurations {
    compileClasspath
}

task packForXCode(type: Sync) {
    final File frameworkDir = new File(buildDir, "xcode-frameworks")
    final String mode = project.findProperty("XCODE_CONFIGURATION")?.toUpperCase() ?: 'DEBUG'
    final def framework = kotlin.targets.ios.binaries.getFramework("common", mode)

    inputs.property "mode", mode
    dependsOn framework.linkTask

    from { framework.outputFile.parentFile }
    into frameworkDir

    doLast {
        new File(frameworkDir, 'gradlew').with {
            text = "#!/bin/bash\nexport 'JAVA_HOME=${System.getProperty("java.home")}'\ncd '${rootProject.rootDir}'\n./gradlew \$@\n"
            setExecutable(true)
        }
    }
}

task iosTest {
    def device = project.findProperty("iosDevice")?.toString() ?: "iPhone 8"
    dependsOn 'linkTestDebugExecutableIos'
    group = JavaBasePlugin.VERIFICATION_GROUP
    description = "Runs tests for target 'ios' on an iOS simulator"

    doLast {
        def binary = kotlin.targets.ios.compilations.test.getBinary('EXECUTABLE', 'DEBUG')
        exec {
            commandLine 'xcrun', 'simctl', 'spawn', device, binary.absolutePath
        }
    }
}

tasks.build.dependsOn packForXCode